include "primitives.alh"
include "modelling.alh"
include "object_operations.alh"
include "library.alh"
include "conformance_scd.alh"

Void function main():
	Element model
	String verify_result

	while (True):
		output("Which model do you want to execute with CBD semantics?")
		model = import_node(input())

		if (element_eq(model, read_root())):
			output("Could not find model; aborting")
		elif (element_neq(model["metamodel"], import_node("models/CausalBlockDiagrams_Design"))):
			output("Not a CBD design model; aborting")
		else:
			verify_result = conformance_scd(model)
			if (verify_result == "OK"):
				output("Model OK!")
				execute_cbd(model)
			else:
				output("Non-conforming model: " + verify_result)

Element function translate_to_runtime(design_model : Element):
	Element runtime_model
	Element all_blocks
	Element all_links
	String mm_type_name
	String element_name
	String attr_name
	String attr_value
	String attribute
	String src
	String dst
	Element all_attributes

	log("Translating to runtime model!")

	log("Creating empty runtime model")
	runtime_model = instantiate_model(import_node("models/CausalBlockDiagrams_Runtime"))

	log("Converting blocks")
	all_blocks = allInstances(design_model, "Block")
	while (list_len(all_blocks) > 0):
		element_name = set_pop(all_blocks)
		mm_type_name = reverseKeyLookup(design_model["metamodel"]["model"], dict_read_node(design_model["type_mapping"], design_model["model"][element_name]))
		instantiate_node(runtime_model, mm_type_name, element_name)
		all_attributes = getAttributeList(design_model, element_name)
		while (read_nr_out(all_attributes) > 0):
			attr_name = set_pop(all_attributes)
			if (bool_not(set_in(runtime_model["model"], read_attribute(design_model, element_name, attr_name)))):
				instantiate_attribute(runtime_model, element_name, attr_name, read_attribute(design_model, element_name, attr_name))
		log("    Converted block " + element_name)

	// Don't merge this together with the block conversion, as the destination block might not exist yet!
	log("Relinking blocks")
	all_links = allInstances(design_model, "Link")
	while (read_nr_out(all_links) > 0):
		element_name = set_pop(all_links)
		src = reverseKeyLookup(design_model["model"], read_edge_src(design_model["model"][element_name]))
		dst = reverseKeyLookup(design_model["model"], read_edge_dst(design_model["model"][element_name]))
		instantiate_link(runtime_model, "Link", element_name, src, dst)
		log((("    Relinked blocks " + src) + " and ") + dst)

	log("Resetting initial conditions")
	all_links = allInstances(design_model, "InitialCondition")
	while (read_nr_out(all_links) > 0):
		element_name = set_pop(all_links)
		src = reverseKeyLookup(design_model["model"], read_edge_src(design_model["model"][element_name]))
		dst = reverseKeyLookup(design_model["model"], read_edge_dst(design_model["model"][element_name]))
		instantiate_link(runtime_model, "InitialCondition", element_name, src, dst)
		log("    Reset IC of " + dst)

	log("Creating schedule at time = 0")
	create_schedule(runtime_model, True)

	log("Creating schedule at time > 0")
	create_schedule(runtime_model, False)

	log("Solving loops (TODO)")

	log("DONE!")
	return runtime_model!

Void function create_schedule(model : Element, is_time_zero : Boolean):
	Element all_blocks
	Element visited
	Element to_visit
	Element incoming_links
	String schedule
	String element_name
	String link
	String source
	String new_schedule
	Boolean ready

	all_blocks = allInstances(model, "Block")
	visited = create_node()
	to_visit = create_node()
	if (is_time_zero):
		schedule = instantiate_node(model, "Schedule", "schedule_init")
	else:
		schedule = instantiate_node(model, "Schedule", "schedule_run")
	instantiate_attribute(model, schedule, "active", True)

	while (read_nr_out(all_blocks) > 0):
		element_name = set_pop(all_blocks)
		if (bool_not(set_in(visited, element_name))):
			list_append(to_visit, element_name)

		while (list_len(to_visit) > 0):
			element_name = list_read(to_visit, list_len(to_visit) - 1)
			if (reverseKeyLookup(model["metamodel"]["model"], dict_read_node(model["type_mapping"], model["model"][element_name])) == "DelayBlock"):
				if (is_time_zero):
					incoming_links = allIncomingAssociationInstances(model, element_name, "InitialCondition")
				else:
					incoming_links = create_node()
			else:
				incoming_links = allIncomingAssociationInstances(model, element_name, "Link")
			ready = True

			while (list_len(incoming_links) > 0):
				link = set_pop(incoming_links)
				source = readAssociationSource(model, link)
				if (bool_not(set_in(visited, source))):
					list_append(to_visit, source)
					ready = False

			if (ready):
				new_schedule = instantiate_node(model, "Schedule", "")
				instantiate_attribute(model, new_schedule, "active", False)
				instantiate_link(model, "LinkedBlock", "", schedule, element_name)
				instantiate_link(model, "NextSchedule", "", schedule, new_schedule)
				schedule = new_schedule
				list_delete(to_visit, list_len(to_visit) - 1)
				set_add(visited, element_name)

	return !

String function readType(model : Element, name : String):
	return reverseKeyLookup(model["metamodel"]["model"], dict_read_node(model["type_mapping"], model["model"][name]))!

Void function list_CBD(model : Element):
	Element all_elements
	String elem
	String block
	
	output("Blocks:")
	all_elements = allInstances(model, "Block")
	while (read_nr_out(all_elements) > 0):
		elem = set_pop(all_elements)
		output((("    " + elem) + ": ") + readType(model, elem))

	output("Links:")
	all_elements = allInstances(model, "Link")
	while (read_nr_out(all_elements) > 0):
		elem = set_pop(all_elements)
		output((("    " + reverseKeyLookup(model["model"], read_edge_src(model["model"][elem]))) + " --> ") + reverseKeyLookup(model["model"], read_edge_dst(model["model"][elem])))

	output("Initial conditions:")
	all_elements = allInstances(model, "InitialCondition")
	while (read_nr_out(all_elements) > 0):
		elem = set_pop(all_elements)
		output((("    " + reverseKeyLookup(model["model"], read_edge_src(model["model"][elem]))) + " --> ") + reverseKeyLookup(model["model"], read_edge_dst(model["model"][elem])))

	output("Schedule (== 0):")
	elem = "schedule_init"
	log("Model " + cast_e2s(model["model"][elem]))
	while (read_nr_out(allOutgoingAssociationInstances(model, elem, "LinkedBlock")) > 0):
		block = readAssociationDestination(model, set_pop(allOutgoingAssociationInstances(model, elem, "LinkedBlock")))
		output("    " + block)
		elem = readAssociationDestination(model, set_pop(allOutgoingAssociationInstances(model, elem, "NextSchedule")))

	output("Schedule (> 0):")
	elem = "schedule_run"
	log("Model " + cast_e2s(model["model"][elem]))
	while (read_nr_out(allOutgoingAssociationInstances(model, elem, "LinkedBlock")) > 0):
		block = readAssociationDestination(model, set_pop(allOutgoingAssociationInstances(model, elem, "LinkedBlock")))
		output("    " + block)
		elem = readAssociationDestination(model, set_pop(allOutgoingAssociationInstances(model, elem, "NextSchedule")))

	return !

Void function execute_cbd(model : Element):
	model = translate_to_runtime(model)

	String cmd
	while (True):
		output("Which operation do you want to execute?")
		cmd = input()

		if (cmd == "help"):
			output("Supported operations:")
			output("  start   -- start simulation")
			output("  pause   -- pause simulation")
			output("  modify  -- live modelling: modify model structure")
			output("  list    -- list blocks and connections")
			output("  help    -- this information")
			output("  exit    -- select another model")
		elif (cmd == "list"):
			list_CBD(model)
		elif (cmd == "exit"):
			return!
		else:
			output("Did not understand command!")
			output("Use 'help' for a list of available options")