modelverse/bootstrap/metamodels.alc

include "primitives.alh"
include "object_operations.alh"
include "library.alh"
include "conformance_scd.alh"
include "modelling.alh"

Element function constraint_integer(model : Element, name : String):
	if (is_physical_int(model["model"][name])):
		return "OK"
	else:
		return "Integer has non-integer instance"

Element function create_metamodels():
	if (bool_not(dict_in(dict_read(read_root(), "__hierarchy"), "models"))):
		Element scd
		scd = instantiate_bottom()

		// Initial model, typed using LTM_bottom
		model_add_node(scd, "Class")
		model_add_node(scd, "Any")
		model_add_node(scd, "String")
		model_add_value(scd, "name", "name")
		model_add_edge(scd, "Association", "Class", "Any")
		model_add_edge(scd, "Inheritance", "Class", "Class")
		model_add_edge(scd, "Association_attribute", "Association", "String")
		model_add_edge(scd, "Association_name", "Association_attribute", "name")
		model_add_edge(scd, "assoc_inh_class", "Association", "Class")
		model_add_edge(scd, "class_inh_any", "Class", "Any")
		model_add_edge(scd, "string_inh_any", "String", "Any")

		// Retype to a "real" LTM, which happens to be itself
		retype_model(scd, scd)
		define_inheritance(scd, "Inheritance")
		retype(scd, "Class", "Class")
		retype(scd, "Any", "Class")
		retype(scd, "String", "Class")
		retype(scd, "name", "String")
		retype(scd, "Association", "Association")
		retype(scd, "Inheritance", "Association")
		retype(scd, "Association_attribute", "Association")
		retype(scd, "Association_name", "Association_attribute")
		retype(scd, "assoc_inh_class", "Inheritance")
		retype(scd, "class_inh_any", "Inheritance")
		retype(scd, "string_inh_any", "Inheritance")

		// Add some attributes, now that it is an ordinary model
		instantiate_node(scd, "Class", "Integer")
		instantiate_link(scd, "Association", "lc", "Class", "Integer")
		instantiate_attribute(scd, "lc", "name", "lower_cardinality")
		instantiate_link(scd, "Association", "uc", "Class", "Integer")
		instantiate_attribute(scd, "uc", "name", "upper_cardinality")
		instantiate_link(scd, "Association", "slc", "Association", "Integer")
		instantiate_attribute(scd, "slc", "name", "source_lower_cardinality")
		instantiate_link(scd, "Association", "suc", "Association", "Integer")
		instantiate_attribute(scd, "suc", "name", "source_upper_cardinality")
		instantiate_link(scd, "Association", "tlc", "Association", "Integer")
		instantiate_attribute(scd, "tlc", "name", "target_lower_cardinality")
		instantiate_link(scd, "Association", "tuc", "Association", "Integer")
		instantiate_attribute(scd, "tuc", "name", "target_upper_cardinality")

		// Add in the Action Language metamodel
		instantiate_node(scd, "Class", "Action")
		instantiate_node(scd, "Class", "Statement")
		instantiate_node(scd, "Class", "Expression")
		instantiate_node(scd, "Class", "funcdef")
		instantiate_node(scd, "Class", "param")
		instantiate_node(scd, "Class", "if")
		instantiate_node(scd, "Class", "break")
		instantiate_node(scd, "Class", "while")
		instantiate_node(scd, "Class", "continue")
		instantiate_node(scd, "Class", "assign")
		instantiate_node(scd, "Class", "return")
		instantiate_node(scd, "Class", "output")
		instantiate_node(scd, "Class", "declare")
		instantiate_node(scd, "Class", "global")
		instantiate_node(scd, "Class", "access")
		instantiate_node(scd, "Class", "constant")
		instantiate_node(scd, "Class", "input")
		instantiate_node(scd, "Class", "resolve")
		instantiate_node(scd, "Class", "call")
		instantiate_link(scd, "Association", "dict_link", "Action", "Any")
		instantiate_link(scd, "Association", "to_str", "dict_link", "String")
		instantiate_attribute(scd, "to_str", "name", "name")
		instantiate_link(scd, "Inheritance", "", "Action", "Any")
		instantiate_link(scd, "Inheritance", "", "funcdef", "Action")
		instantiate_link(scd, "Inheritance", "", "param", "Action")
		instantiate_link(scd, "Inheritance", "", "Statement", "Action")
		instantiate_link(scd, "Inheritance", "", "Expression", "Action")
		instantiate_link(scd, "Inheritance", "", "resolve", "Statement")
		instantiate_link(scd, "Inheritance", "", "if", "Statement")
		instantiate_link(scd, "Inheritance", "", "break", "Statement")
		instantiate_link(scd, "Inheritance", "", "continue", "Statement")
		instantiate_link(scd, "Inheritance", "", "global", "Statement")
		instantiate_link(scd, "Inheritance", "", "while", "Statement")
		instantiate_link(scd, "Inheritance", "", "assign", "Statement")
		instantiate_link(scd, "Inheritance", "", "return", "Statement")
		instantiate_link(scd, "Inheritance", "", "call", "Statement")
		instantiate_link(scd, "Inheritance", "", "declare", "Statement")
		instantiate_link(scd, "Inheritance", "", "call", "Expression")
		instantiate_link(scd, "Inheritance", "", "access", "Expression")
		instantiate_link(scd, "Inheritance", "", "constant", "Expression")
		instantiate_link(scd, "Inheritance", "", "input", "Expression")
		instantiate_link(scd, "Association", "statement_next", "Statement", "Statement")
		instantiate_link(scd, "Association", "if_cond", "if", "Expression")
		instantiate_link(scd, "Association", "if_true", "if", "Statement")
		instantiate_link(scd, "Association", "if_false", "if", "Statement")
		instantiate_link(scd, "Association", "while_cond", "while", "Expression")
		instantiate_link(scd, "Association", "while_body", "while", "Statement")
		instantiate_link(scd, "Association", "assign_var", "assign", "Any")
		instantiate_link(scd, "Association", "assign_value", "assign", "Expression")
		instantiate_link(scd, "Association", "break_while", "break", "while")
		instantiate_link(scd, "Association", "continue_while", "continue", "while")
		instantiate_link(scd, "Association", "return_value", "return", "Expression")
		instantiate_link(scd, "Association", "resolve_var", "resolve", "Any")
		instantiate_link(scd, "Association", "access_var", "access", "Any")
		instantiate_link(scd, "Association", "constant_node", "constant", "Any")
		instantiate_link(scd, "Association", "output_node", "output", "Expression")
		instantiate_link(scd, "Association", "global_var", "global", "String")
		instantiate_link(scd, "Association", "param_name", "param", "String")
		instantiate_link(scd, "Association", "param_value", "param", "Expression")
		instantiate_link(scd, "Association", "param_next_param", "param", "param")
		instantiate_link(scd, "Association", "funcdef_body", "funcdef", "Statement")
		instantiate_link(scd, "Association", "call_func", "call", "Expression")
		instantiate_link(scd, "Association", "call_params", "call", "param")
		instantiate_link(scd, "Association", "call_last_param", "call", "param")

		// Now still allow for constraints on classes
		instantiate_link(scd, "Association", "constraint", "Class", "funcdef")
		instantiate_attribute(scd, "constraint", "name", "constraint")

		// Finally done, so export!
		export_node("models/SimpleClassDiagrams", scd)

		// Now for some examples: a PetriNet
		Element pn
		pn = instantiate_model(scd)
		define_inheritance(pn, "Inheritance")
		instantiate_node(pn, "Class", "Place")
		instantiate_node(pn, "Class", "Transition")
		instantiate_node(pn, "Class", "Integer")
		instantiate_link(pn, "Association", "P2T", "Place", "Transition")
		instantiate_link(pn, "Association", "T2P", "Transition", "Place")
		instantiate_link(pn, "Association", "Place_tokens", "Place", "Integer")
		instantiate_attribute(pn, "Place_tokens", "name", "tokens")
		instantiate_attribute(pn, "Place_tokens", "target_lower_cardinality", 1)
		instantiate_attribute(pn, "Place_tokens", "target_upper_cardinality", 1)
		instantiate_link(pn, "Association", "P2T_weight", "P2T", "Integer")
		instantiate_attribute(pn, "P2T_weight", "name", "weight")
		instantiate_attribute(pn, "P2T_weight", "target_lower_cardinality", 1)
		instantiate_attribute(pn, "P2T_weight", "target_upper_cardinality", 1)
		instantiate_link(pn, "Association", "T2P_weight", "T2P", "Integer")
		instantiate_attribute(pn, "T2P_weight", "name", "weight")
		instantiate_attribute(pn, "T2P_weight", "target_lower_cardinality", 1)
		instantiate_attribute(pn, "T2P_weight", "target_upper_cardinality", 1)

		// Add constraint on the Integer
		add_constraint(pn, "Integer", constraint_integer)

		// Add global constraints
		set_model_constraints(pn, petrinet_constraints)
		export_node("models/PetriNets", pn)

		Element ltm_bottom
		ltm_bottom = instantiate_bottom()
		model_add_node(ltm_bottom, "Node")
		model_add_edge(ltm_bottom, "Edge", "Node", "Node")
		model_add_edge(ltm_bottom, "inheritance", "Node", "Node")
		model_add_edge(ltm_bottom, "__inh", "Edge", "Node")

		retype_model(ltm_bottom, ltm_bottom)
		define_inheritance(ltm_bottom, "inheritance")
		retype(ltm_bottom, "Node", "Node")
		retype(ltm_bottom, "Edge", "Edge")
		retype(ltm_bottom, "inheritance", "Edge")
		retype(ltm_bottom, "__inh", "inheritance")

		export_node("models/LTM_bottom", ltm_bottom)

	return dict_read(dict_read(read_root(), "__hierarchy"), "models")

String function petrinet_constraints(model : Element):
	// Check places to have positive number of tokens
	Element all_elems
	String elem_constraint
	
	log("Check constraints")
	all_elems = allInstances(model, "Place")
	log("Got all instances")
	log("Length " + cast_i2s(list_len(all_elems)))
	log("First element: " + cast_e2s(all_elems[0]))
	while (0 < list_len(all_elems)):
		elem_constraint = set_pop(all_elems)
		log("Check Place " + elem_constraint)
		if (integer_lt(read_attribute(model, elem_constraint, "tokens"), 0)):
			return "Negative number of tokens in Place " + elem_constraint

	// Check P2T transitions to have positive weight
	log("Check constraints 2")
	all_elems = allInstances(model, "P2T")
	log("Got all instances")
	while (0 < read_nr_out(all_elems)):
		elem_constraint = set_pop(all_elems)
		log("Check P2T " + elem_constraint)
		if (integer_lt(read_attribute(model, elem_constraint, "weight"), 0)):
			return "Negative weight in arc " + elem_constraint

	// Check T2P transitions to have positive weight
	log("Check constraints 3")
	all_elems = allInstances(model, "T2P")
	log("Got all instances")
	while (0 < read_nr_out(all_elems)):
		elem_constraint = set_pop(all_elems)
		log("Check T2P " + elem_constraint)
		if (integer_lt(read_attribute(model, elem_constraint, "weight"), 0)):
			return "Negative weight in arc " + elem_constraint

	return "OK"