modelverse/bootstrap/conformance_scd.alc

include "primitives.alh"
include "library.alh"
include "object_operations.alh"
include "constructors.alh"
include "modelling.alh"

Boolean function is_direct_instance(model : Element, instance : String, type : String):
	// Just check whether or not the type mapping specifies the type as the type of the instance
	return element_eq(dict_read_node(model["type_mapping"], model["model"][instance]), model["metamodel"]["model"][type])

Boolean function is_nominal_instance(model : Element, instance : String, type : String):
	if (bool_not(dict_in(model["metamodel"]["model"], type))):
		// type is not even in the specified metamodel, so this will never work
		return False

	if (bool_not(dict_in_node(model["type_mapping"], model["model"][instance]))):
		// Doesn't even have a type
		return False

	return is_nominal_subtype(model["metamodel"], reverseKeyLookup(model["metamodel"]["model"], dict_read_node(model["type_mapping"], model["model"][instance])), type)

Boolean function is_nominal_subtype(metamodel : Element, subclass : String, superclass : String):
	if (element_eq(metamodel["model"][subclass], metamodel["model"][superclass])):
		return True

	if (bool_not(dict_in(metamodel["model"], subclass))):
		return False

	if (bool_not(dict_in(metamodel["model"], superclass))):
		return False

	Element superclasses
	Element new_superclass
	Element result

	superclasses = get_superclasses(metamodel, subclass)

	while (0 < list_len(superclasses)):
		new_superclass = set_pop(superclasses)
		if (is_nominal_subtype(metamodel, new_superclass, superclass)):
			return True
	
	return False

String function conformance_scd(model : Element):
	// Initialization
	Element keys
	Element metamodel
	Element typing
	String model_name
	Element src_model
	Element dst_model
	Element src_metamodel
	Element dst_metamodel
	Element element
	Element check_list
	String check_type
	Element cardinalities
	Element scd

	// Load in variables
	scd = import_node("models/SimpleClassDiagrams")
	metamodel = model["metamodel"]
	typing = model["type_mapping"]
	cardinalities = create_node()

	// Create dictionary with all associations and allowed cardinalities
	if (list_len(model["model"]) > 0):
		keys = dict_keys(metamodel["model"])
		Integer slc
		Integer suc
		Integer tlc
		Integer tuc
		String key
		Element tmp_dict

		while (0 < list_len(keys)):
			key = set_pop(keys)
			if (is_nominal_instance(metamodel, key, "Association")):
				tmp_dict = create_node()
				slc = read_attribute(metamodel, key, "source_lower_cardinality")
				suc = read_attribute(metamodel, key, "source_upper_cardinality")
				tlc = read_attribute(metamodel, key, "target_lower_cardinality")
				tuc = read_attribute(metamodel, key, "target_upper_cardinality")

				if (element_neq(slc, read_root())):
					dict_add(tmp_dict, "slc", slc)
				if (element_neq(suc, read_root())):
					dict_add(tmp_dict, "suc", suc)
				if (element_neq(tlc, read_root())):
					dict_add(tmp_dict, "tlc", tlc)
				if (element_neq(tuc, read_root())):
					dict_add(tmp_dict, "tuc", tuc)

				if (list_len(tmp_dict) > 0):
					dict_add(cardinalities, key, tmp_dict)

		// Iterate over each element of the model, finding out whether everything is fine
		keys = dict_keys(model["model"])
		while (0 < list_len(keys)):
			model_name = set_pop(keys)
			element = model["model"][model_name]

			if (bool_not(dict_in_node(typing, element))):
				return "Model has no type specified: " + model_name

			if (bool_not(set_in_node(metamodel["model"], dict_read_node(typing, element)))):
				return "Type of element not in specified metamodel: " + model_name

			if (bool_not(is_nominal_instance(model, model_name, reverseKeyLookup(metamodel["model"], dict_read_node(typing, element))))):
				return "Element is not an instance of its specified type: " + model_name

			if (is_edge(element)):
				src_model = reverseKeyLookup(model["model"], read_edge_src(element))
				dst_model = reverseKeyLookup(model["model"], read_edge_dst(element))
				src_metamodel = reverseKeyLookup(metamodel["model"], read_edge_src(dict_read_node(typing, element)))
				dst_metamodel = reverseKeyLookup(metamodel["model"], read_edge_dst(dict_read_node(typing, element)))

				if (bool_not(is_nominal_instance(model, src_model, src_metamodel))):
					return "Source of model edge not typed by source of type: " + model_name

				if (bool_not(is_nominal_instance(model, dst_model, dst_metamodel))):
					return "Destination of model edge not typed by source of type: " + model_name

			if (dict_in(cardinalities, model_name)):
				// Check cardinality for all of our edges
				//
				//      SLC..SUC     TLC..TUC
				//   A  ---------------------> B
				//
				// First the incoming, so we are at B in the above figure
				Integer lower_val
				Integer upper_val
				Integer instances

				check_list = selectPossibleOutgoing(model, model_name, dict_keys(cardinalities))
				while (0 < list_len(check_list)):
					check_type = set_pop(check_list)
					if (dict_in(cardinalities, check_type)):
						// Cardinalities defined for this association, so check them
						lower_val = cardinalities[check_type]["tlc"]
						upper_val = cardinalities[check_type]["tuc"]
						instances = list_len(allOutgoingAssociationInstances(model, model_name, check_type))
						if (dict_in(cardinalities[check_type], "tlc")):
							// A lower cardinality was defined at the target
							if (integer_gt(cardinalities[check_type]["tlc"], instances)):
								return "Lower cardinality violation for outgoing edge at " + model_name
						if (dict_in(cardinalities[check_type], "tuc")):
							// An upper cardinality was defined at the target
							if (integer_lt(cardinalities[check_type]["tuc"], instances)):
								return "Upper cardinality violation for outgoing edge at " + model_name

				// Identical, but for outgoing, and thus for A in the figure
				check_list = selectPossibleIncoming(model, model_name, dict_keys(cardinalities))
				while (0 < list_len(check_list)):
					check_type = set_pop(check_list)
					if (dict_in(cardinalities, check_type)):
						// Cardinalities defined for this association, so check them
						lower_val = cardinalities[check_type]["slc"]
						upper_val = cardinalities[check_type]["suc"]
						instances = list_len(allIncomingAssociationInstances(model, model_name, check_type))
						if (dict_in(cardinalities[check_type], "slc")):
							// A lower cardinality was defined at the source
							if (integer_gt(cardinalities[check_type]["slc"], instances)):
								return "Lower cardinality violation for incoming edge at " + model_name
						if (dict_in(cardinalities[check_type], "suc")):
							// An upper cardinality was defined at the source
							if (integer_lt(cardinalities[check_type]["suc"], instances)):
								return "Upper cardinality violation for incoming edge at " + model_name

			Element constraint_function
			constraint_function = read_attribute(model, model_name, "constraint")
			if (element_neq(constraint_function, read_root())):
				String result
				// TODO define the local_constraint execution function
				result = execute_local_constraint(model, model_name)
				if (result != "OK"):
					return result

	// Check multiplicities, if they are defined (optional)
	Element metamodel_keys
	String metamodel_element
	Integer attr_value

	metamodel_keys = dict_keys(metamodel["model"])
	while (0 < list_len(metamodel_keys)):
		metamodel_element = set_pop(metamodel_keys)

		// Lower multiplicities
		attr_value = read_attribute(metamodel, metamodel_element, "lower_cardinality")
		if (element_neq(attr_value, read_root())):
			// We have defined a lower cardinality, so check number of instances!
			if (attr_value > list_len(allInstances(model, metamodel_element))):
				return "Lower cardinality violated for class: " + metamodel_element

		// Upper multiplicities
		attr_value = read_attribute(metamodel, metamodel_element, "upper_cardinality")
		if (element_neq(attr_value, read_root())):
			// We have defined a lower cardinality, so check number of instances!
			if (attr_value < list_len(allInstances(model, metamodel_element))):
				return "Upper cardinality violated for class: " + metamodel_element

	// Structure seems fine, now do static semantics
	if (dict_in(metamodel, "constraints")):
		Element constraint_function
		constraint_function = metamodel["constraints"]
		return constraint_function(model)
	else:
		return "OK"

Element function set_model_constraints(model : Element, func : Element):
	if (dict_in(model, "constraints")):
		dict_delete(model, "constraints")
	dict_add(model, "constraints", func)
	return model

Element function generate_bottom_type_mapping(model : Element):
	Element mm
	mm = model["metamodel"]["model"]
	dict_delete(model, "type_mapping")
	Element tm
	tm = create_node()
	dict_add(model, "type_mapping", tm)
	
	// Iterate over every element
	Element elem_keys
	Element elem
	elem_keys = dict_keys(model["model"])
	while (0 < read_nr_out(elem_keys)):
		elem = model["model"][set_pop(elem_keys)]
		if (is_edge(elem)):
			dict_add(tm, elem, mm["Edge"])
		else:
			dict_add(tm, elem, mm["Node"])

	return model

String function execute_local_constraint(model : Element, element : String):
	Element action
	Element params
	Element param
	Element second_param

	action = read_attribute(model, element, "constraint")
	params = create_node()
	param = create_node()
	dict_add(param, "name", "a")
	dict_add(param, "value", model)
	second_param = create_node()
	dict_add(second_param, "name", "b")
	dict_add(second_param, "value", element)
	dict_add(param, "next_param", second_param)
	dict_add(params, "params", param)
	dict_add(params, "last_param", second_param)
	return eval(action, params)