include "primitives.alh"
include "object_operations.alh"
include "typing.alh"

Boolean function find_type_mapping(model : Element):
	// Finds a correct type mapping for the provided model (with partial type mapping)
	// We go through several phases:
	//   1) remove elements from type mapping that are not in the model or metamodel
	//   2) find a mapping based on the current partial mapping
	//   3) (optional) verify that the mapping is correct with conformance checking
	// Returns True if the type mapping was altered

	// Start of with some initialization
	Boolean result
	Element tm
	Element elems
	String elem

	result = False
	tm = get_type_mapping_as_dict(model)

	// 1) remove elements from type mapping that are not in the model or metamodel
	elems = dict_keys(tm)
	while (set_len(elems) > 0):
		elem = set_pop(elems)
		if (bool_not(dict_in(model["model"], elem))):
			// Remove the key, as the model does not contain the element anymore
			dict_delete(tm, elem)
		else:
			if (bool_not(dict_in(model["metamodel"]["model"], tm[elem]))):
				// Remove the key, as the metamodel does not contain the type anymore
				dict_delete(tm, elem)
		
	// 2) find a mapping based on the current partial mapping, but only if it is not yet complete
	if (dict_len(model["model"]) > dict_len(tm)):
		result = True
		// TODO for now, this only returns something for a simple case, where the MM has one edge, and one node
		//      and it makes the assumption that SCD is the M3 level...

		// First find the name of the edge and node elements
		Element elems
		String elem

		String node_element
		String edge_element

		elems = dict_keys(model["metamodel"]["model"])
		while (set_len(elems) > 0):
			elem = set_pop(elems)

			if (bool_not(is_edge(elem))):
				node_element = elem
			else:
				// Is an edge, but might be the inheritance link...
				if (read_type(model["metamodel"]["model"], elem) != "Inheritance"):
					// Is not the inheritance link
					edge_element = elem

		// Now we have bot an edge_element and node_element of the metamodel
		// Now just trivially bind all elements!
		elems = dict_keys(model["model"])
		while (set_len(elems) > 0):
			elem = set_pop(elems)

			if (is_edge(elem)):
				retype(model, elem, edge_element)
			else:
				retype(model, elem, node_element)

	// 3) (optional) verify that the mapping is correct with conformance checking
	// TODO
	// If not, set the result to read_root()
	
	return result!