reset
set terminal postscript enhanced colour portrait size 6,4

set out 'model/mvs_latency_sweep.eps'
set title "MvK to MvS latency simulation"
set xlabel "Latency (ms)"
set ylabel "Execution time (s)"
set key off
set logscale y
set style histogram
set style data histograms
set boxwidth 0.9 relative
set style fill solid 1.0 border -1
set xtics rotate
plot 'model/results_mvs_latency' u 2:xtic(1) title "Execution time"

set out 'model/mvi_latency_sweep.eps'
set title "MvI to MvK latency simulation"
plot 'model/results_mvi_latency' u 2:xtic(1) title "Execution time"

set out 'model/mvs_latency_performance.eps'
set title "MvK to MvS latency influence"
set key top left
plot 'model/results_mvs_latency' u 2:xtic(1) title "Execution time", '' u 3:xtic(1) title "Simulation time" linecolor rgb "#00FF00"

set out 'model/mvi_latency_performance.eps'
set title "MvI to MvK latency influence"
set yrange [100:1200]
plot 'model/results_mvi_latency' u 2:xtic(1) title "Execution time", '' u 3:xtic(1) title "Simulation time" linecolor rgb "#00FF00"

reset
set terminal postscript enhanced colour portrait size 6,4
set out 'model/execution_jitter.eps'
set title "Execution time jitter"
set xlabel "Execution time (s)"
set ylabel "Samples"
set key off
set style fill solid 1.0 noborder
bin_width = 2.0;
set boxwidth bin_width absolute
bin_number(x) = floor(x/bin_width)
rounded(x) = bin_width * (bin_number(x) + 0.5)
plot 'model/results_real' u (rounded($1)):(1) smooth frequency with boxes