DTDesign/models/ontology/oml/ftg.oml

vocabulary <http://ontology.rys.one/drivetrain/vocabulary/ftg#> as ftg {
    extends <http://www.w3.org/2001/XMLSchema#> as xsd
    extends <http://purl.org/dc/elements/1.1/> as dc
    extends <http://www.w3.org/2000/01/rdf-schema#> as rdfs

    @rdfs:comment ""
    aspect Element [key hasId]
    aspect Node :> Element []
    aspect Edge :> Element []
    aspect Port :> Element []
    aspect TypedNode :> Node []
    concept Activity         :> TypedNode []
    concept Initial          :> Node []
    concept Final            :> Node []
    concept Fork             :> Node []
    concept Join             :> Node []
    concept Artefact         :> TypedNode []
    concept ArtefactInstance :> TypedNode []
    concept Formalism        :> Node []
    concept Transformation   :> Node []
    concept TraceEvent       :> Node []
    concept ControlFlow :> Edge []
    concept DataFlow    :> Edge []
    concept TypeFlow    :> Edge []
    concept ControlPort :> Port []
    concept DataPort    :> Port []

    scalar property hasId [
        domain Element
        range xsd:string
        functional
    ]

    scalar property hasPortName [
        domain Port
        range xsd:string
    ]

    scalar property hasNodeName [
        domain Node
        range xsd:string
    ]

    scalar property hasNodeType [
        domain TypedNode
        range xsd:string
    ]

    scalar property hasLink [
        domain ArtefactInstance
        // Probably should be some URI?
        range xsd:string
    ]

    scalar property refersToPortName [
        domain TraceEvent
        range xsd:string
    ]

    enumerated scalar PortDirection [
        "in",
        "out"
    ]

    scalar property hasPortDirection [
        domain Port
        range PortDirection
        functional
    ]

    enumerated scalar EventType [
        "begin",
        "end"
    ]

    scalar property isOfEventType [
        domain TraceEvent
        range EventType
        functional
    ]

    concept ControlPortOut :> ControlPort [
        restricts scalar property hasPortDirection to "out"
    ]
    concept ControlPortIn :> ControlPort [
        restricts scalar property hasPortDirection to "in"
    ]
    concept DataPortOut :> ControlPort [
        restricts scalar property hasPortDirection to "out"
    ]
    concept DataPortIn :> ControlPort [
        restricts scalar property hasPortDirection to "in"
    ]

    concept TraceEventBegin :> TraceEvent [
        restricts scalar property isOfEventType to "begin"
    ]
    concept TraceEventEnd :> TraceEvent [
        restricts scalar property isOfEventType to "end"
    ]

    relation entity HasOrigin [
        from Edge
        // Could also be Node, but this is more restrictive
        //to Port, Formalism, Fork, Join, TraceEvent, Transformation, Activity, Artefact, ArtefactInstance, Initial
        to Node
        forward hasOrigin
        reverse isOriginOf
    ]

    relation entity HasDestination [
        from Edge
        //to Port, Formalism, Fork, Join, TraceEvent, Transformation, Activity, Artefact, ArtefactInstance, Final
        to Node
        forward hasDestination
        reverse isDestinationOf
    ]
}