yakindu/test-plugins/org.yakindu.sct.test.models/tests/EntryReactionAction.sctunit

testclass EntryReactionAction for statechart entries.EntryReactionAction {

	/*
	 * Actions on an entry transition should be executed during entering the state machine.
	 */
	@Test
	operation entryTransitionActionOnStatechartEnter(){ 
		
		enter		 
		assert enteredR1
		assert enteredR2
		assert enteredBdefault
		assert ! enteredBother
		
	} 
	
	/*
	 * Actions on an entry transition should be executed if it is used during a run to completion step.
	 */
	@Test
	operation entryOnRTS(){
		init()
		raise b
		proceed 1 cycle
		
		assert ! enteredR1
		assert ! enteredR2
		assert ! enteredBdefault
		assert enteredBother		
		
	}
	
	
	/*
	 * Actions on an entry transition should not be executed if be executed when entering 
	 * a region using a history.
	 */
	@Test
	operation noEntryTransitionActionOnHistory(){
		init()
		raise d
		proceed 1 cycle
		
		assert ! enteredR1
		assert ! enteredR2
		assert ! enteredBdefault
		assert ! enteredBother		
	}

	operation init() :void {
		enter
		
		raise b 
		proceed 1 cycle
		raise d 
		proceed 1 cycle
		
		enteredR1 = false
		enteredR2 = false
		enteredBdefault = false
		enteredBother = false
	}
	
}